Rakenna oma Bluetooth-uutiset

Asetettu päälle 2017-11-13

Esimerkki uutiskirjeestä

Tarvikkeet

Arduino Uno R3 - klooni Varastossa Tai Arduino Nano € 13,45 MAX7219 4x pistematriisimoduuli Varastossa Tämä on näyttö, tarvitset vähintään 1, 2 on vielä parempi! € 10,45 HC-06 Bluetooth-moduuli ja sovitin Varastossa Tämä on HC-06 Bluetooth Slave, tarvitset 1 € 17,45 5,6KΩ Metallikalvovastus 1 / 4W - 100 kpl Varastossa Jännitteenjakaja Bluetooth-moduulille € 2,05 10KΩ Metallikalvovastus 1/4W - 10 kpl Varastossa Jännitteenjakaja Bluetooth-moduulille € 1,80 Mean Well SGA12E09-P1J virtalähde - 9V 1,33A Varastossa Lisätehoa varten USB ei voi toimittaa tarpeeksi € 15,30 Sisäänrakennettu tasavirtapistoke 5,5 mm x 2,1 mm - 5 kpl Loppu varastosta € 2,55 Kaikki yhteensä € 63,05

Aikataulu:

Kaavakuva näyttää, kuinka kaikki pitäisi yhdistää. Jos saat jo pyörivän tunteen kaikista noista johdoista, älä katso liikaa kokonaisuutta, vaan yritä harkita ja yhdistää moduulit yksitellen. Näet, että se ei ole liian huono.

Kaavakuva näyttää vain yhden nelinkertaisen pistematriisi-LED-moduulin, todellisuudessa voit yhdistää kaksi kaksinkertaista leveyttä!

Viestitaulun kytkentäkaavio

Bluetooth-moduuli vaatii hieman ylimääräistä huomiota. Bluetooth-viestintäsignaalit (TX ja RX) toimivat 3,3 voltilla, kun taas Arduino toimii 5 voltilla. Kaksi vastusta vähentävät Arduino 5 volttia noin 3,3 volttiin.

Ravitsemus:
Näet, että käytössä on 5 voltin virtalähde. Sinun täytyy. USB -liitäntään kytketty Arduino ei pysty syöttämään tarpeeksi virtaa LED-matriisin käyttämiseen, etenkään kaksoimatriisin kanssa.

Arduino kirjasto ja luonnos:

Arduino luonnos käyttää kahta ulkoista kirjastoa, joiden asentamiseksi etsi kirjastonhallinnasta MD_MAX72xx. Asenna sitten MD_Max72xx ja MD_Parola

Ticker USB Arduino Library

Aseta oikea moduuli:
Kirjastojen asentamisen jälkeen meidän on kerrottava MD_Max72xx-kirjastolle, mitä led-matriisimoduulia käytämme.

Etsi tiedosto kiintolevyltäsi: MD_MAX72xx.h
(luultavasti kansiossa C:\Käyttäjät\nimesi\Dokumentit\ Arduino \kirjastot\MD_MAX72XX\src\)

//Op regel 214, zie je staan:   
#define   USE_PAROLA_HW   1, verander die 1 in 0

//Op regel 237 zie je staan: 
#define   USE_FC16_HW   0,   verander die 0 in 1.

Arduino Sketch:

Sitten voimme nyt ladata luonnoksen.
Kopioi luonnos ja liitä koodi Arduino ohjelmistoon, valitse oikea com-portti ja kirjoita Arduino ja paina latauspainiketta!

#include <MD_Parola.h>
#include <MD_MAX72xx.h>
#include <SPI.h>
#include <SoftwareSerial.h>
#include <EEPROM.h>
#define MAX_DEVICES 8
#define CLK_PIN   13
#define DATA_PIN  11
#define CS_PIN    10

// Use softserial for the bluetooth module
SoftwareSerial mySerial(2, 3);

// HARDWARE SPI
MD_Parola LK = MD_Parola(CS_PIN, MAX_DEVICES);

uint8_t scrollSpeed = 30;    // default frame delay value
textEffect_t scrollEffect = PA_SCROLL_LEFT;
textPosition_t scrollAlign = PA_LEFT;
uint16_t scrollPause = 2000; // in milliseconds

// Global message buffers shared by Serial and Scrolling functions
#define  BUF_SIZE  75
char curMessage[BUF_SIZE];
char newMessage[BUF_SIZE];
bool newMessageAvailable = false;

void setup()
{
  // Enable the next line to clear the message from eeprom.
  // EEPROM.write(0,1);
  
  mySerial.begin(9600); 
  delay(500);
  
  // The next line configures the BT-04 (BT-06) Module to NOT report connection status. 
  mySerial.write("\r\nAT+ENABLEIND0\r\n"); 
  delay(100);
  ClearRXbuffer();
  
  // change the name of the BT-04 (BT-06) device, this will not work for HC-06
  mySerial.write("AT+NAMELichtkrant01\r\n"); 
  delay(100);
  ClearRXbuffer();
  
  LK.begin();
  LK.displayClear();
  LK.displaySuspend(false);
  LK.displayText(curMessage, scrollAlign, scrollSpeed, scrollPause, scrollEffect, scrollEffect);  

  // Get the last message from EEPROM
  getMessageFromEeprom();
}


void loop()
{  
  readSerial();
  if (LK.displayAnimate())
  {
    if (newMessageAvailable)
    {
      strcpy(curMessage, newMessage);
      newMessageAvailable = false;
      storeMessageInEeprom();
    }
    LK.displayReset();
  }
}


  
void readSerial(void) {
  static char *cp = newMessage;
  while (mySerial.available())  
  {
    *cp = (char)mySerial.read();
    if ( (*cp == '\r') || (*cp == '\n') || (cp - newMessage >= BUF_SIZE-2)) // end of message character or full buffer
    {
      *cp = '\0'; // end the string   
      cp = newMessage;
      newMessageAvailable = true;
      mySerial.print("Nieuwe Boodschap = ");
      mySerial.println(newMessage);
      ClearRXbuffer();
    }
    else  // move char pointer to next position
      cp++;
  }
}


void storeMessageInEeprom(){
  // Store the message in EEPROM
  EEPROM.write(0,251);
  int i=0;
  char c=curMessage[i];
  while (c !=0){
    EEPROM.write(i+1,c);
    i++;
    c=curMessage[i];
    }
    EEPROM.write(i+1,0);
}

void getMessageFromEeprom(){
  if (EEPROM.read(0)!=251){
    strcpy(curMessage, "Hello! Please Send new message over bluetooth");
    newMessage[0] = '\0';
    } else {      
      int i=0;
      char c = EEPROM.read(i+1);
      while (c!=0){
        curMessage[i++]=c;
        c = EEPROM.read(i+1);
        }
        curMessage[i] = '\0';
        newMessageAvailable=false;         
    }
}

void ClearRXbuffer(){
  while (mySerial.available()){
    char c=mySerial.read(); 
    delay(5);
    } 
}

Jos kaikki on hyvin (ja miksi ei?), näet nyt viestin "Hei, lähetä uusi viesti bluetoothilla". Joten on korkea aika asentaa Android-sovellus puhelimeesi ja lähettää uusi viesti Bluetoothin kautta!

Android-sovellus:

Uutiskirjeen tekstin muuttamiseksi tarvitsemme Bluetooth-pääteohjelman, esimerkiksi Kai Morichin Serial Bluetooth Terminalin, Sovelluskauppa.

SerialBluetooth-pääte

Sovelluksen toiminta on melko itsestään selvää, mutta näytän sen videolla askel askeleelta.

bluetooth-pääte

Huomio: Applen iOS ei voi muodostaa yhteyttä käytettyyn Bluetooth-moduuliin, joten tämä toimii vain Android-laitteiden kanssa.

Katso video

Onko vielä epäselvyyksiä? Voit katsoa kaikkea tarkemmin tällä videolla.

lähettänyt Bart Venneker Verkkosivusto | Youtube Bart Venneker on elektroniikkaharrastaja ja tekee opetusvideoita elektroniikasta, Arduino ja 3d-tulostimista.