Arduino Uno 74HC4051 (MUX/DEMUX) -testerinä

Asetettu päälle 2019-10-04

74HC4051 testaus

74HC4051 on multiplekseri/demultiplekseri-IC. Tämän testaamiseksi Arduino Unoa voidaan käyttää kahden 74HC4051 IC:n kanssa. Ensimmäinen IC toimii multiplekserina, toinen demultiplekserina.

Sokka irti

Pin	Label	Toiminto
1	A4	Kanava sisään/ulos
2	A6	Kanava sisään/ulos
3	A	Yhteinen sisään/ulos
4	A7	Kanava sisään/ulos
5	A5	Kanava sisään/ulos
6	~E	Ota käyttöön (negatiivinen)
7	Nautakarja	Negatiivinen virtalähde
8	GND	Maadoitus (0V)
9	Vcc	Virtalähde (5Vdc)
10	A2	Kanava sisään/ulos
11	A1	Kanava sisään/ulos
12	A0	Kanava sisään/ulos
13	A3	Kanava sisään/ulos
14	S0	Osoiterivin bitti 0
15	S1	Osoiterivin bitti 1
16	S2	Osoiterivin bitti 2

Digitaalinen testaus

Vaikka 74HC4051 on analoginen MUX/DEMUX, sitä ei voi testata analogisesti Arduino Unon kanssa, koska sillä ei ole analogisia lähtöjä (DAC). Myöhemmin tässä artikkelissa kuvataan, kuinka tämä voidaan saavuttaa DAC Breakout -kortilla. Digitaaliseen testaukseen tarvitaan vain Arduino kortti ja 2 IC:tä.

Kytkeä

Aseta molempien IC:iden nasta 16 (Vcc) arvoon 5 VDC; nasta 8 (GND) 0V jännitteellä.

Liitä molempien IC:iden nastat 6 (~E) ja 7 (Vee) myös GND:hen.

Liitä seuraavat molempien IC:iden nastat: 1,2,4,5,15,16,13,12 (A0...A7).

Liitä molempien IC:iden nastat 11 (S0) Arduino korttiin A0:ssa.

Liitä molempien IC:iden nasta 12 (S1) Arduino korttiin A1:ssä.

Liitä molempien IC:iden nastat 13 (S2) Arduino korttiin A2:ssa.

Liitä IC 1:stä nasta 3 (A) A4:n Arduino korttiin.

Liitä IC 2:sta nasta 3 (A) A5:n Arduino korttiin.

Arduino koodi

Käytä seuraavaa koodia Arduino

Test 74HC4051 MUX/DEMUX met Arduino Uno

/****************************************************************
      Configuratie
****************************************************************/
#define pinS0   A0 // Address select 0
#define pinS1   A1 // Address select 1
#define pinS2   A2 // Address select 2
#define pinA_ic1  A4    // A pin on IC1
#define pinA_ic2  A5    // A pin on IC2
/*****   EINDE CONFIGUTATIE    *****/

// Poll timer
unsigned long lastPoll;

/****************************************************************
      SETUP
****************************************************************/
void setup()
{
  Serial.begin(115200);
  while (!Serial) {
    ; // Wacht op seriele monitor
  }
  Serial.println("--- Seriele monitor gestart ---");

  // Configureer pinnen als uitgangen
  pinMode(pinS0, OUTPUT);
  pinMode(pinS1, OUTPUT);
  pinMode(pinS2, OUTPUT);
  pinMode(pinA_ic1, OUTPUT);
  // Configureer pinnen als ingangen
  pinMode(pinA_ic2, INPUT);

  lastPoll = millis();
}

/****************************************************************
      LOOP
****************************************************************/
void loop()
{
  static byte byteCounter = 0;
  static bool writeBit;
  static bool readBit;
  String testResult;

  // Genereer willekeurig true of false
  writeBit = bool(random(0, 2));

  // Elke 500ms
  if (millis() - lastPoll >= 500)
  {
    // Selecteer adres
    selectAddress(byteCounter);

    // Schrijf bit naar IC 1
    digitalWrite(pinA_ic1, writeBit);

    // Lees bit van IC 2
    readBit = digitalRead(pinA_ic2);

    if (writeBit == readBit) {
      testResult = " -> OK";
    }
    else {
      testResult = " -> NIET OK";
    }
    

    // In de seriële monitor moet bit schrijf = bit lees
    Serial.print("Op adres " );
    Serial.print(byteCounter, BIN);
    Serial.print(" is schrijf (IC 1) vs lees (IC 2): " );
    Serial.print(writeBit);
    Serial.print(" / ");
    Serial.print(readBit);
    Serial.print(testResult);
    Serial.println();

    // Selecteer volgend adres 
    byteCounter++;
    if (byteCounter > 7) {
      byteCounter = 0;  // Reset counter at 1000 (count 0000 to 0111)
    }
    lastPoll = millis();
  }
}

/****************************************************************
      Zet de Sx pinnen om het gewenste adres te selecteren
****************************************************************/
void selectAddress(byte address) {
  // Lees adres bits
  bool S0 = bool(address >> 0 & 0x01); // Shift rechts en maskeer met 0x01
  bool S1 = bool(address >> 1 & 0x01);
  bool S2 = bool(address >> 2 & 0x01);

  // Zet adres lijnen correct
  digitalWrite(pinS0, S0);
  digitalWrite(pinS1, S1);
  digitalWrite(pinS2, S2);
}
//EINDE

Tuloksena on jotain tässä genressä:

Op adres 0 is schrijf (IC 1) vs lees (IC 2): 1 / 1 -> OK
Op adres 1 is schrijf (IC 1) vs lees (IC 2): 0 / 0 -> OK
Op adres 10 is schrijf (IC 1) vs lees (IC 2): 0 / 0 -> OK
Op adres 11 is schrijf (IC 1) vs lees (IC 2): 1 / 1 -> OK
Op adres 100 is schrijf (IC 1) vs lees (IC 2): 0 / 0 -> OK
Op adres 101 is schrijf (IC 1) vs lees (IC 2): 0 / 0 -> OK
Op adres 110 is schrijf (IC 1) vs lees (IC 2): 1 / 1 -> OK
Op adres 111 is schrijf (IC 1) vs lees (IC 2): 0 / 0 -> OK
Op adres 0 is schrijf (IC 1) vs lees (IC 2): 0 / 0 -> OK
Op adres 1 is schrijf (IC 1) vs lees (IC 2): 1 / 1 -> OK
Op adres 10 is schrijf (IC 1) vs lees (IC 2): 1 / 1 -> OK
Op adres 11 is schrijf (IC 1) vs lees (IC 2): 0 / 0 -> OK

Komponentit

Tämän testin komponentit:

Komponenttiluettelo

74HC4051 multiplekseri - 5 kpl Loppu varastosta (myyty 5 kpl) € 3,70 Leipälauta 400 pistettä - valkoinen Loppu varastosta € 1,95 Uros-uros neulesetti 65 osaa Varastossa € 3,05 Kaikki yhteensä € 8,70

Samalla tavalla voit testata versiota Breakout Boardilla

SparkFun Multiplexer Breakout - 8 Channel (74HC4051)Avaa 74HC4051:n koko potentiaali Sparkfun Multiplexer Breakoutin avulla. Muunna neljä I/O-nastaa kahdeksaksi valittavaksi signaaliksi, jotka sopivat useisiin sovelluksiin. Helppokäyttöinen, luotettava ja monipuolinen sekä harrastajalle että ammattilaiselle. Varastossa € 4,20

Analoginen testaus

Analogian testaamiseen tarvitset DAC:n. Arduino Unossa tätä ei ole vakiona, mutta " Adafruit MCP4725 (12bit DAC)" Breakout-kortin avulla voit mahdollisesti saavuttaa tämän.

MCP4725 Breakout Board - 12-bittinen DAC ja I2C-liitäntäMikro-ohjaimessasi on luultavasti ADC (analogi -> digitaalimuunnin), mutta onko siinä DAC (digitaali -> analoginen muunnin)? Nyt se voi! Tässä breakout-kortissa on helppokäyttöinen 12-bittinen MCP4725 DAC. Ohjaa sitä I2C:n kautta ja lähetä sille arvo, jonka haluat sen tuottavan, ja VOUT-nastalla on se. Toimitetaan 10 - 30 päivässä € 5,85

Kytkeä

Tämän jälkeen liitäntä on säädettävä:
Aseta IC 1:n nasta 3 (A) MCP4725:n (VOU) lähtöön (A5:n sijaan)
Aseta IC 2:n nasta 3 (A) Arduino levyn nastalle A3 (A4:n sijaan).
Arduino levyn nastat A4 (SCA) ja A5 (SCL) on liitettävä MCP4725:n SDA- ja SCL-liitäntöihin.
Liitä myös MCP4725-kortin VDD ja GND 5V:iin ja GND:hen.
Yhdistä MCP4725:n nasta A0 GND:hen valitaksesi I2C-osoitteen 0x62.
(Vaihtoehto: Valitse A0 jännitteellä 5 V osoitteessa 0x63.)

Adafruit kirjastot

Adafruit MCP4725 DAC:n ohjaamiseksi on suositeltavaa ladata vastaava kirjasto Adafruit .
Löydät nämä osoitteesta Github.

Analogisen testauksen koodi on sitten seuraava:

Test 74HC4051 MUX/DEMUX met Arduino Uno en DAC

// Voeg MCP4725 DAC bibliotheek toe
#include <Wire.h>               // I2C library
#include >Adafruit_MCP4725.h>   // Adafruit library for MCP4725 (DAC)
Adafruit_MCP4725 dac;

/****************************************************************
      Configuratie
****************************************************************/
#define pinS0   A0 // Address select 0
#define pinS1   A1 // Address select 1
#define pinS2   A2 // Address select 2
#define pinA_ic2  A3    // A pin on IC2
/*****   EINDE CONFIGUTATIE    *****/

// Poll timer
unsigned long lastPoll;

/****************************************************************
      SETUP
****************************************************************/
void setup()
{
  Serial.begin(115200);
  while (!Serial) {
    ; // Wacht op seriele monitor
  }
  Serial.println("--- Seriele monitor gestart ---");

  // Configureer pinnen als uitgangen
  pinMode(pinS0, OUTPUT);
  pinMode(pinS1, OUTPUT);
  pinMode(pinS2, OUTPUT);

  dac.begin(0x62);  // MCP4725, pin A0 ligt op GND
  // dac.begin(0x63);  // MCP4725, pin A0 ligt op 5V

  lastPoll = millis();
}

/****************************************************************
      LOOP
****************************************************************/
void loop()
{
  static byte byteCounter = 0;
  uint16_t writeChannel; // 12 bit (0-4095)
  uint16_t readChannel;  // 10 bit (0-1023)
  String testResult;

  // Genereer willekeurige analoge uitgang waarde
  writeChannel = random(0, 4096); // random 0-4095 (!)

  // Elke 500ms
  if (millis() - lastPoll >= 500)
  {
    // Selecteer adres
    selectAddress(byteCounter);

    // Schrijf naar DAC
    dac.setVoltage(writeChannel, false);

    // Lees analoge waarde van analoge ingang op Arduino
    readChannel = analogRead(pinA_ic2);

    // Converteer waarden naar volt
    writeChannel = map(writeChannel, 0, 4095, 0, 500);
    readChannel = map(readChannel, 0, 1023, 0, 500);

    // Zijn beide waarden gelijk ?
    if (writeChannel == readChannel) {
      testResult = " -> OK";
    }
    else {
      testResult = " -> NIET OK";
    }

    // In de seriële monitor moet schrijf waarde = lees waarde
    Serial.print("Op adres " );
    Serial.print(byteCounter, BIN);
    Serial.print(" is schrijf (IC 1) vs lees (IC 2): " );
    Serial.print(float(writeChannel)/100);
    Serial.print(" / ");
    Serial.print(float(readChannel)/100);
    Serial.print(testResult);
    Serial.println();

    // Selecteer volgend adres 
    byteCounter++;
    if (byteCounter > 7) {
      byteCounter = 0;  // Reset counter at 1000 (count 0000 to 0111)
    }
    lastPoll = millis();
  }
}

/****************************************************************
      Set the Sx pins to select proper address
****************************************************************/
void selectAddress(byte address) {
  // Lees adres bits
  bool S0 = bool(address >> 0 & 0x01); // Shift rechts en maskeer met 0x01
  bool S1 = bool(address >> 1 & 0x01);
  bool S2 = bool(address >> 2 & 0x01);

  // Zet adres lijnen correct
  digitalWrite(pinS0, S0);
  digitalWrite(pinS1, S1);
  digitalWrite(pinS2, S2);
}
//EINDE

Sarjanäytön tulos on tässä genressä:

Op adres 10 is schrijf (IC 1) vs lees (IC 2): 3.40 / 3.40 -> OK
Op adres 11 is schrijf (IC 1) vs lees (IC 2): 4.21 / 4.21 -> OK
Op adres 100 is schrijf (IC 1) vs lees (IC 2): 0.08 / 0.08 -> OK
Op adres 101 is schrijf (IC 1) vs lees (IC 2): 1.54 / 1.54 -> OK
Op adres 110 is schrijf (IC 1) vs lees (IC 2): 1.53 / 1.53 -> OK
Op adres 111 is schrijf (IC 1) vs lees (IC 2): 4.02 / 4.02 -> OK
Op adres 0 is schrijf (IC 1) vs lees (IC 2): 0.82 / 0.82 -> OK
Op adres 1 is schrijf (IC 1) vs lees (IC 2): 0.93 / 0.93 -> OK
Op adres 10 is schrijf (IC 1) vs lees (IC 2): 3.72 / 3.72 -> OK
Op adres 11 is schrijf (IC 1) vs lees (IC 2): 1.35 / 1.35 -> OK
Op adres 100 is schrijf (IC 1) vs lees (IC 2): 2.64 / 2.64 -> OK
Op adres 101 is schrijf (IC 1) vs lees (IC 2): 1.29 / 1.29 -> OK
Op adres 110 is schrijf (IC 1) vs lees (IC 2): 2.89 / 2.88 -> NIET OK
Op adres 111 is schrijf (IC 1) vs lees (IC 2): 3.54 / 3.54 -> OK
Op adres 0 is schrijf (IC 1) vs lees (IC 2): 4.24 / 4.24 -> OK
Op adres 1 is schrijf (IC 1) vs lees (IC 2): 1.51 / 1.51 -> OK
Op adres 10 is schrijf (IC 1) vs lees (IC 2): 4.20 / 4.20 -> OK

Ajoittain esiintyy "virheitä" pyöristyksestä ja epätarkkuuksista johtuen. Voit esimerkiksi nähdä, että 2,89 V ei ole yhtä suuri kuin 2,88 V. Yhdessä kaikkien muiden onnistuneiden tulosten kanssa voit kuitenkin olettaa, että MUX/DEMUX toimii täydellisesti.

lähettänyt Arashi Verkkosivusto

Arduino Uno 74HC4051 (MUX/DEMUX) -testerinä

74HC4051 testaus

Sokka irti

Digitaalinen testaus

Kytkeä

Arduino koodi

Test 74HC4051 MUX/DEMUX met Arduino Uno

Komponentit

Komponenttiluettelo

Analoginen testaus

Kytkeä

Adafruit kirjastot

Test 74HC4051 MUX/DEMUX met Arduino Uno en DAC

Kommentit