Arduino Leonardo - elektroninen lukko

Asetettu päälle 2020-06-22

Vika koodissa EEPROM-muistissa

Nyt voimme saada koodin, tarkistaa sen, mutta entä sen tallentaminen. Koska kun nollaat Arduino RAM tyhjennetään, joten meidän on löydettävä toinen tapa tallentaa se ja pystyä muuttamaan sitä lataamatta ohjelmaa uudelleen. Tässä EEPROM astuu peliin...

Joten meidän on käytettävä EEPROM-kirjastoa.

Storing and Getting the code from EEPROM

#include <EEPROM.h>

unsigned char Eeprom_PasscodeLength = 0;

void GetEepromCode() {
   EEPROM.get(0, Eeprom_PasscodeLength);
   if (Eeprom_PasscodeLength) {
      NewPasscodeLength = Eeprom_PasscodeLength;
      for (unsigned char i = 0; i < Eeprom_PasscodeLength; i++) {
        EEPROM.get(i + 1, Master[i]);
      }
   }
   else {
    NewPasscodeLength = PasscodeLength;
    return;
   }
   PasscodeLength = NewPasscodeLength;
}

void WriteEepromCode(){
  EEPROM.put(0, PasscodeLength);
  for (unsigned char i = 0; i < PasscodeLength; i++) {
    EEPROM.put(i + 1, Master[i]);
  }
}

Joten nyt voimme tallentaa ja saada koodin EEPROM:ista, on aika sallia sen muuttaa koodi, kun ohjelma on vielä käynnissä Arduino .

Changing the code while the program is running

void CheckNewCode() {
  if (EnableDebug) {
    Serial.print("dataCountBuff1: ");
    Serial.println(dataCountBuff1);
    Serial.print("dataCountBuff2: ");
    Serial.println(dataCountBuff2);
    Serial.print("codeBuff1: ");
    Serial.println(code_buff1);
    Serial.print("codeBuff2: ");
    Serial.println(code_buff2);
  }  
  if (dataCountBuff1 == dataCountBuff2) {
      if(!strcmp(code_buff1, code_buff2)){
          NewPasscodeLength = dataCountBuff2;
          for (unsigned char i = 0; i <= MaxPasscodeLength; i++) {
            Master[i] = 0;
          }
          
          for (unsigned char i = 0; i <= NewPasscodeLength; i++) {
            Master[i] = code_buff1[i];
          }

          if (EnableDebug) {
            Serial.println();
            Serial.print("Master: ");
            Serial.println(Master);
          }
          lcd.clear();
          lcd.print("Passcodes Match");
          _delay_ms(1000);
          lcd.clear();
        }
     else {
        NewPasscodeLength = PasscodeLength;
        lcd.clear();
        lcd.setCursor(0,0);
        lcd.print("Codes do not match");
        if (EnableDebug) {
          Serial.println();
          Serial.println("Passcodes do not match");
        }
        _delay_ms(1000);
        lcd.clear();
     }
  }
  else {
    NewPasscodeLength = PasscodeLength;
    lcd.clear();
    lcd.setCursor(0,0);
    lcd.print("Codes do not match");
    if (EnableDebug) {
      Serial.println();
      Serial.println("Passcodes are not the same length");
    }
    _delay_ms(1000);
    lcd.clear();
  }
  clearData();
}

void ChangeCode() {
    dataCountBuff1 = 0;
    dataCountBuff2 = 0;
    for (unsigned char i = 0; i <= MaxPasscodeLength; i++) {
      code_buff1[i] = 0;
      code_buff2[i] = 0;
    }
    if (EnableDebug) {
      Serial.println();
      Serial.println("Changing Master");
    }
    lcd.clear();
    lcd.print("Enter new code:");
    lcd.setCursor(0,2);
    lcd.print("press * to confirm");
    Key = WaitForKey();
    while(Key != '*') {
      GetCode();
      Key = WaitForKey();
    }
    Data[data_count] = 0;
    dataCountBuff1 = data_count;
    for (unsigned char i =0; i <= data_count; i++) {
      code_buff1[i] = Data[i];
    }
    clearData();
    lcd.clear();
    _delay_ms(500);
    lcd.print("Confirm new code:");
    lcd.setCursor(0,2);
    lcd.print("press * to confirm");
    Key = WaitForKey();
    while (Key != '*') {
      GetCode();
      Key = WaitForKey();
    }
    Data[data_count] = 0;
    dataCountBuff2 = data_count;
    for (unsigned char i =0; i <= data_count; i++) {
      code_buff2[i] = Data[i];
    }
    clearData();
    CheckNewCode();
    PasscodeLength = NewPasscodeLength;
    if (EnableDebug) {
      Serial.print("PasscodeLength: ");
      Serial.println(PasscodeLength);
    }
    WriteEepromCode();
}

Edellinen sivu 8. Koodi - osa 3 - Koodi Tämänhetkinen sivu 9. Koodi - osa 4 - Lisää koodeja Seuraava sivu 10. Koodi - osa 5 - Setup and Loop 1. Johdanto 2. Kaavio 3. Näppäimistö 4. LCD-moduuli 5. Servo 6. Koodi - osa 1 - Näppäimistö 7. Koodi - osa 2 - LCD 8. Koodi - osa 3 - Koodi 9. Koodi - osa 4 - Lisää koodeja 10. Koodi - osa 5 - Setup and Loop 11. Koko koodi lähettänyt Sander Speetjens

Arduino Leonardo - elektroninen lukko

Vika koodissa EEPROM-muistissa

Storing and Getting the code from EEPROM

Changing the code while the program is running

Kommentit