Arduino Leonardo - elektroninen lukko

Asetettu päälle 2020-06-22

Koodin saaminen käyttäjän syötteestä

Joten kuten kuvailin osassa 1, meidän on saatava kaikki vaaditut syötteet käyttäjältä ja tarkistettava koodi tallennetulla koodilla.

Ja tarkista myös, ettei näyttö vuoda yli. Se käsitellään tällä koodilla.

GetCode function

const unsigned char MaxPasscodeLength = 19;
unsigned char PasscodeLength;
char Data[MaxPasscodeLength];
char Master[MaxPasscodeLength];

unsigned char data_count = 0;
char Key;

void GetCode() {							// This piece of code handles getting the code from the user
   if (data_count < MaxPasscodeLength) {
    Data[data_count] = Key; 
    lcd.setCursor(data_count,1); 
    lcd.print("*");
    if (EnableDebug) {
      Serial.println();
      Serial.print("Data_count: ");
      Serial.println(data_count);
      Serial.print("Data: ");
      Serial.println(Data[data_count]);
    }
    data_count++;
   }
   else {
      lcd.setCursor(data_count,1);
      lcd.print("*");
      lcd.setCursor(0, 3);
      lcd.print("Passcode Overflow");
      if (EnableDebug) {
        Serial.println();
        Serial.println("Passcode Overflow Error");
      }
      _delay_ms(1000);
      lcd.clear();
      clearData();
   }
}

Tarkistetaan koodia

Meidän on myös tarkistettava, vastaako koodi tallennettua koodia, jotta tiedämme milloin voimme avata lukon ja milloin emme.

CheckCode Function

void CodeCorrect() {
  lcd.clear();
  lcd.setCursor(0,0);
  lcd.print("Correct");
  LockState = true;
  _delay_ms(1000);
  if (EnableDebug) {
    Serial.println();
    Serial.println("Opened");
  }
}

void CodeIncorrect() {
  lcd.clear();
  lcd.setCursor(0,0);
  lcd.print("Incorrect");
  if (EnableDebug) {
    Serial.println();
    Serial.println("Incorrect PSWD");
  }
  LockState = false;
  _delay_ms(1000);
}

void OpenLock() {
  if (EnableServo) {
    Lock.write(90);
  }
  lcd.setCursor(0,0);
  lcd.print("Lock Opened");
  lcd.setCursor(0,2);
  lcd.print("Press -* to lock");
  if (EnablePasscodeChange) {
    lcd.setCursor(3,3);
    lcd.print("-# to change code");
  }
  TimeLastActivity = millis();
}

void CloseLock() {
  if (EnableServo) {
    Lock.write(180);
  }
  LockState = false;
  lcd.clear();
  if (EnableDebug) {
    Serial.println();
    Serial.println("Closing");
  }
  TimeLastActivity = millis();
}

void CheckCode() {
  if(data_count == PasscodeLength){
      Data[PasscodeLength] = 0;
      _delay_ms(500);
      lcd.clear();
      if (EnableDebug) {
        Serial.println();
        Serial.print("Data:   ");
        Serial.println(Data);
        Serial.print("Master: ");
        Serial.println(Master);
      }
      if(!strcmp(Data, Master)){
          CodeCorrect();
        }

      else{
          if (EnableDebug) {
            Serial.println();
            Serial.print("PasscodeLength: ");
            Serial.println(PasscodeLength);
            Serial.print("DataCount: ");
            Serial.println(data_count);
          }
          CodeIncorrect();
        }
  }
  else {
      if (EnableDebug) {
        Serial.println();
        Serial.print("Data:   ");
        Serial.println(Data);
        Serial.print("Master: ");
        Serial.println(Master);
        Serial.println();
        Serial.print("PasscodeLength: ");
        Serial.println(PasscodeLength);
        Serial.print("DataCount: ");
        Serial.println(data_count);
      }
      CodeIncorrect();
    }
  lcd.clear();
  clearData();
}

Edellinen sivu 7. Koodi - osa 2 - LCD Tämänhetkinen sivu 8. Koodi - osa 3 - Koodi Seuraava sivu 9. Koodi - osa 4 - Lisää koodeja 1. Johdanto 2. Kaavio 3. Näppäimistö 4. LCD-moduuli 5. Servo 6. Koodi - osa 1 - Näppäimistö 7. Koodi - osa 2 - LCD 8. Koodi - osa 3 - Koodi 9. Koodi - osa 4 - Lisää koodeja 10. Koodi - osa 5 - Setup and Loop 11. Koko koodi lähettänyt Sander Speetjens

Arduino Leonardo - elektroninen lukko

Koodin saaminen käyttäjän syötteestä

GetCode function

Tarkistetaan koodia

CheckCode Function

Kommentit