Aina ajoissa DS1307 ja DS3231 REAL aikakellomoduulien kanssa

Asetettu päälle 2016-07-16

REAL time kellomoduulit

REAL time kellon versiot

REAL aikakellosarja sisältää monia erityyppisiä numeroita, joilla kaikilla on vertailukelpoinen toiminta. Tässä sarjassa vain 2 versiota on "valtavirtaa", nimittäin DS1307 ja DS3231. Näissä siruissa on sekä mahdollisuus liittää akku että sqw-lähtönasta, jolla ohjain voi vastaanottaa kellopulssin (1 Hz, 1,024 kHz, 4,096 kHz, 8,192 kHz). Molemmissa IC:issä on myös One-Wire-liitäntä, joka mahdollistaa niiden liittämisen I:n kautta²osoitteeseen C.

DS1302 reaaliaikainen kellomoduuli - SPIDS1302 Real Time Clock Modulessa on SPI-liitäntä, jonka kautta se voi kertoa ajan. Varastossa € 1,90

REAL DS3231REAL DS3231-sirun kanssa. Tämä moduuli varmistaa, että Arduino tietää tarkan ajan aina. Yhdistämällä Arduino 'sqw'-pintaan, on mahdollista generoida sekunti välein keskeytys, jolla anturiarvoja tai näyttöä voidaan käsitellä. Varastossa € 4,05

RTC-moduulin liittäminen Arduino UNO:hon

RTC-moduuleita on eri muotoisia ja kokoisia, mutta liitäntä Arduino on sama kaikille moduuleille. Moduuli on joka tapauksessa saatava 5 V jännitteellä, lisäksi I2C-liitäntä on kytkettävä Arduino SDA (Serial data) SCL (Serial clock) -nastoihin (nämä ovat Arduino UNO:n nastat A4 ja A5). Lisäksi SQW-lähtö voidaan kytkeä mihin tahansa Arduino nastan vastaanottamaan kellopulssi RTC:ltä.

DS1307-liitäntä Arduino UNO

BC koodi

RTC-sirujen numeroarvot tallennetaan BCD-muodossa. BCD-koodia on helpompi käyttää kuin desimaalilukuja laitteistotasolla, mutta nämä koodit eivät ole kovin hyödyllisiä ohjelmistoissa. Sirulle tulevat ja sieltä tulevat numerot on siksi koodattava ja dekoodattava, jotta ohjain ja RTC ymmärtävät toisiaan.

// Convert decimal to BCD
byte decToBcd(byte val)
{
  return( (val/10*16) + (val%10) );
}
//Convert BCD to decimal
byte bcdToDec(byte val)
{
  return( (val/16*10) + (val%16) );
}

Kirjoita nykyinen aika RTC:hen

Aika tarvitsee kirjoittaa RTC:hen vain kerran, kun se on kytketty akkuun. RTC itse pitää ajan ja jatkaa laskemista, vaikka se ei olisi kytkettynä ohjaimeen.

#include "Wire.h"
#define DS3231_I2C_ADDRESS 0x68

void setDS3231time(
    byte second, 
    byte minute, 
    byte hour, 
    byte dayOfWeek, 
    byte dayOfMonth, 
    byte month, 
    byte year)
{
  Wire.beginTransmission(DS3231_I2C_ADDRESS);
  
  //set next input to start at the seconds register
  Wire.write(0); 
  
  //set seconds
  Wire.write(decToBcd(second)); 
  //set minutes
  Wire.write(decToBcd(minute)); 
  //set hours
  Wire.write(decToBcd(hour)); 
  //set day of week (1=Sunday, 7=Saturday)
  Wire.write(decToBcd(dayOfWeek));  
  //set date (1 to 31)
  Wire.write(decToBcd(dayOfMonth)); 
  //set month
  Wire.write(decToBcd(month));
  //set year 20(0 to 99)
  Wire.write(decToBcd(year)); 
    
  Wire.endTransmission();
}

Kiintolevyn kello

De tijd van de RTC lezen

#include "Wire.h"
#define DS3231_I2C_ADDRESS 0x68

void readDS3231time(
    byte *second,
	byte *minute,
	byte *hour,
	byte *dayOfWeek,
	byte *dayOfMonth,
	byte *month,
	byte *year)
{
  Wire.beginTransmission(DS3231_I2C_ADDRESS);
  //set DS3231 register pointer to 00h
  Wire.write(0); 
  Wire.endTransmission();
      
  //request seven bytes of data from DS3231
  Wire.requestFrom(DS3231_I2C_ADDRESS, 7);
  *second = bcdToDec(Wire.read() & 0x7f);
  *minute = bcdToDec(Wire.read());
  *hour = bcdToDec(Wire.read() & 0x3f);
  *dayOfWeek = bcdToDec(Wire.read());
  *dayOfMonth = bcdToDec(Wire.read());
  *month = bcdToDec(Wire.read());
  *year = bcdToDec(Wire.read());
}

Näytä aika

Kun nämä toiminnot yhdessä, Arduino voi määrittää ajan. Alla olevalla toiminnolla nämä tiedot kirjoitetaan sarjamonitoriin, mutta mahdollisuudet ajan näyttämiseen ovat rajattomat.

void setup()
{
  Wire.begin();
  Serial.begin(9600);
  
  //set the initial time (only once, not every startup)
  //seconds, minutes, hours, dayofweek, day, month, year
  //11:00:00, Saturday, 2016-07-16
  setDS3231time(00,00,11,7,16,7,16);
}

void displayTime()
{
  byte second, minute, hour; 
  byte dayOfWeek, dayOfMonth, month, year;
  
  //retrieve data
  readDS3231time(&second, &minute, &hour, &dayOfWeek, 				     &dayOfMonth, &month, &year);
    
  //Hour
  Serial.print(hour, DEC);
  Serial.print(":");
  //Minute (+0 if needed)
  if (minute<10)
  {
    Serial.print("0");
  }
  Serial.print(minute, DEC);
  Serial.print(":");
  //Second (+0 if needed)
  if (second<10)
  {
    Serial.print("0");
  }
  Serial.print(second, DEC);
  Serial.print(" ");
    
  //Day
  Serial.print(dayOfMonth, DEC);
  Serial.print("/");
  //Month
  Serial.print(month, DEC);
  Serial.print("/");
  //Year
  Serial.print(year, DEC);
}


void loop()
{
  displayTime(); 
  delay(1000);
}

SQW frequentie instellen

#include "Wire.h"
#define DS3231_I2C_ADDRESS 0x68

void setup()
{
  Wire.begin();
  Serial.begin(9600);
  
  Wire.beginTransmission(DS3231_I2C_ADDRESS);
  
  //move pointer to SQW address
  Wire.write(0x07); 
 
  //set output clock speed
  //0x00 = Off
  //0x10 = 1Hz
  //0x11 = 4.096Hz
  //0x12 = 8.192Hz
  //0x13 = 32.768Hz
  Wire.write(0x10);
 
  Wire.endTransmission();  
}

Tällä koodilla voidaan rakentaa täydellinen kello, joka voi näyttää kellonajan. Tämä voidaan tehdä 7-segmenttisellä näytöllä, analogisena kellona, savusignaaleilla tai se voidaan jopa puhua pyydettäessä. Lisäksi aikaa voidaan käyttää myös kotiautomaatiossa/kotiautomaatiossa, kahvinkeitin kytkeytyy päälle aamulla klo 8, mikroaaltouuni klo 17.15 illalla ja verhot sulkeutuvat klo 19.01.05. Kaikki on mahdollista.

lähettänyt Robin Blok Verkkosivusto Olen kiinnostunut elektroniikasta, ohjelmoinnista ja erityisesti näiden yhdistämisestä. Opencircuit kirjoitan blogeja, joissa selitän kuinka elektroniikka ja moduulit toimivat.